home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Computer Life 1995 December
/
Computer Life December 1995.iso
/
tapcis
/
whatsnew.scr
< prev
next >
Wrap
INI File
|
1995-10-08
|
3KB
|
107 lines
[*About this script*]
This script captures stories from "What's New on CompuServe", placing each
story in a separate message in the message file.
By default, this script captures stories from CompuServe's main What's New
menu. If you would like to capture the European What's New stories as well,
change the line "Europe=No" to "Europe=Yes" under the [*Variables*] heading
below. To capture only the European stories, also change the line
"WhatsNew=Yes" to "WhatsNew=No" under the same heading.
;This script isn't necessarily a good model of how to handle multi-page
;menus of articles. The stories in What's New don't consistently lead back
;to the menu page from which they were read. So this script "counts" the
;submenus, and GO's back to the first page after each group of stories.[]
Loren Jenkins [76702,1006] - May, 1995
Revised:
04-Jun-95 - fixed to handle variations in story headings (lj)
[*Script Setup*]
Title=What's New on CompuServe
[*Variables*]
WhatsNew=Yes
Europe=No
[Begin]
Echo "Script to capture What's New articles"
if ( @capName$ = "" ) Let @capName$ = @pathMsg$ @svcName$ '.MSG'
Let @hdrNum = @On
Let oldEcho = @echo
WaitList
1 = "^JMORE !"
2 = "^J!"
EndList
if ( WhatsNew ) goto 'StartWhatsNew'
if ( Europe ) goto 'StartEurope'
goto 'Finished'
[StartWhatsNew]
Let @hdrSec$ = "0 What's New on CompuServe"
Let gopage$ = 'GO CIS:NEW'
Let command$ = gopage$
Let menuToRead# = 1
Let lastPage = @No
Let WhatsNew = @No
goto 'GetMenu'
[StartEurope]
if ( gopage$ ) Echo "European What's New"
Let @hdrSec$ = "1 European What's New"
Let gopage$ = 'GO CIS:EURONEW'
Let command$ = gopage$
Let menuToRead# = 1
Let lastPage = @No
Let Europe = @No
goto 'GetMenu'
[GetMenu]
Send command$
DoWaitMenu stories[]
Set @echo @off
if ( @waitMatch# = 2 ) let lastPage = @True
if ( command$ = gopage$ ) Let menuPage# = 1
if ( menuPage# = menuToRead# ) goto 'ReadMenu'
[GetNextMenu]
if ( lastPage ) goto 'Finished'
Let menuPage# = menuPage# + 1
Let command$ = ''
Goto 'GetMenu'
[ReadMenu]
ForEach in stories[] gosub "ReadArticle"
Let menuToRead# = menuToRead# + 1
Let command$ = gopage$
Goto 'GetMenu'
[ReadArticle]
; skip the menu choices that aren't articles
if ( @strstr(@arrValue$, "special events/contests") ) return
if ( @strstr(@arrValue$, "what's new archives") ) return
if ( @strstr(@arrValue$, "more what's new stories") ) return
if ( @strstr(@arrValue$, "what's new in europe") ) return
Let @hdrSub$ = @arrValue$
Send @arrItem$
Wait "^J"
Echo "Capturing story " @arritem$ "/" @arrvalue$
Wait "^J"
Wait "^J"
CapHeader
Wait "^JLast page."
Wait "!"
CapClose
Return
[Finished]
if ( Europe ) goto 'StartEurope'
Set @echo oldEcho
Send '^M'
Wait '!'
Echo "End of script"
End